home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD001b.dsk / LEARNIT.bas < prev    next >
BASIC Source File  |  2003-06-12  |  2KB  |  70 lines
  1. 10  REM  LEARNIT
  2. 20  REM 
  3. 30  REM  NEIL R. CARLSON, LEARNIT, A MEMORIZATION AID PROGRAM, ON COMPUTING, 3(1):72-78, 1981
  4. 40  REM  AUTHOR'S ADDRESS: 
  5. 50  REM  64 HARKNESS ROAD
  6. 60  REM  PELHAM, MASS 01002
  7. 80  DIM TX$(24): DIM LT(24): DIM SP(24,80): DIM X$(24): REM  24X40 CRT SCREEN
  8. 90  GOSUB 660: REM  CLEAR SCREEN
  9. 100  PRINT "THIS PROGRAM WILL HELP YOU MEMORIZE A   POEM, SPEECH, OR ANY OTHER PASSAGE."
  10. 120  PRINT 
  11. 130  PRINT "THE LENGTH OF THE TEXT IS LIMITED BY    THE SIZE OF THE SCREEN."
  12. 135  PRINT 
  13. 140  PRINT "IF THE TEXT IS TOO LONG, LEARN IT IN    PIECES."
  14. 150  PRINT 
  15. 160  PRINT "BEFORE PRESSING RETURN, MAKE SURE THAT  THERE ARE NO MISTAKES IN ANY LINE       BECAUSE ONCE IT IS ENTERED, IT CANNOT   BE CORRECTED."
  16. 180  PRINT 
  17. 190  PRINT "TYPE A $ (DOLLAR SIGN) ON THE LAST LINE TO SIGNAL THAT YOU ARE DONE."
  18. 200  PRINT 
  19. 210  PRINT 
  20. 220  FOR I = 1 TO 24
  21. 230  INPUT TX$(I)
  22. 240  IF TX$(I) = "$" GOTO 260
  23. 250  NEXT I
  24. 260 NL = I -1
  25. 270  GOSUB 660: REM  CLEAR SCREEN
  26. 280  FOR I = 1 TO NL
  27. 290  FOR J = 1 TO  LEN(TX$(I))
  28. 300  IF  MID$ (TX$(I),J,1) < >"  "  THEN LT(I) = LT(I) +1:SP(I,J) = 1
  29. 310  NEXT J
  30. 320  NEXT I
  31. 330  PRINT "PRESS RETURN TO SEE PASSAGE.  WHEN IT   APPEARS READ IT ALOUD VERY CAREFULLY."
  32. 335  PRINT 
  33. 340  PRINT "THEN PRESS RETURN AGAIN, AND SOME OF    THE LETTERS WILL DISAPPEAR."
  34. 345  PRINT 
  35. 350  PRINT "READ THE PASSAGE AGAIN, AND THEN PRESS  RETURN TO ELIMINATE SOME MORE LETTERS."
  36. 355  PRINT 
  37. 360  PRINT "IN TEN PASSES ALL THE LETTERS WILL BE   GONE AND YOU WILL HAVE IT MEMORIZED!"
  38. 380  INPUT DU$
  39. 390  GOSUB 660: REM  CLEAR SCREEN
  40. 400  FOR I = 1 TO NL
  41. 410  PRINT TX$(I)
  42. 420  NEXT I
  43. 430  INPUT DU$
  44. 440  FOR CT = 1 TO 9
  45. 450  FOR L = 1 TO NL
  46. 460 ND =  INT(LT(L)/(11 -CT))
  47. 470  IF ND = 0  THEN  GOTO 550
  48. 480  FOR D = 1 TO ND
  49. 490 CH =  INT( LEN(TX$(L)) * RND(1)) +2
  50. 500  IF SP(L,CH) < >1  THEN 490
  51. 505 X$(L) = " "
  52. 510 TX$(L) =  LEFT$(TX$(L),CH -1) +X$(L) + MID$ (TX$(L),CH +1)
  53. 520 SP(L,CH) = 0
  54. 530 LT(L) = LT(L) -1
  55. 540  NEXT D
  56. 550  NEXT L
  57. 560  GOSUB 660: REM  CLEAR SCREEN
  58. 570  FOR I = 1 TO NL
  59. 580  PRINT TX$(I)
  60. 590  NEXT I
  61. 600  INPUT DU$
  62. 610  NEXT CT
  63. 620  GOSUB 660: REM  CLEAR SCREEN
  64. 630  PRINT "YOU ARE FINISHED... NOW SEE IF YOU HAVE IT MEMORIZED."
  65. 640  GOTO 700
  66. 650  REM 
  67. 660  REM  CLEAR SCREEN SUBROUTINE
  68. 670  HOME 
  69. 680  RETURN 
  70. 700  END